Exemple de requêtes SPARQL sur la liste des BSV
100 bulletins avec leurs informations associées région, type de culture et date de publication présentées en mode texte
SELECT ?document ?date ?culture ?labregion
WHERE {
?document a vespa:Bulletin .
?document dcterms:date ?date.
?document dcterms:subject ?culture.
?document dcterms:spatial ?region.
?region rdfs:label ?labregion
} LIMIT 100
Liste des types de culture en région Rhône-Alpes
SELECT DISTINCT ?culture ?labregion
WHERE {
?document a vespa:Bulletin .
?document dcterms:subject ?culture.
?document dcterms:spatial ?region.
?region rdfs:label ?labregion
FILTER REGEX(?labregion, "rh.ne.?alpes", "i")
}
Ne sachant pas comment est orthographiée la région, le filtre se base sur des expressions régulières, ce qui permet au passage de préciser l'insensibilité à la casse (le "i"). Le point, dans l'expression régulière, peut être remplacé par n'importe quel caractère et le point d'interrogation signifie que le caractère qui précède est optionnel.
100 bulletins avec l'ensemble des dates extraites des différents processus
SELECT ?document ?date ?dateT ?dateF ?dateG ?dateM ?dateV WHERE {
?document a vespa:Bulletin .
?document dcterms:date ?date.
?document vespa:textExtractionDate ?dateT.
OPTIONAL { ?document vespa:filenameDate ?dateF.}
OPTIONAL { ?document vespa:gateContentDate ?dateG.}
OPTIONAL {?document vespa:dateMetadata ?dateM.}
OPTIONAL {?document vespa:pestObserverDate ?dateV.}
} LIMIT 100
Quels sont les bulletins publiés entre le 15 juillet 2013 et 15 août 2015 heure de Paris et qui traitent d'Arboriculture (annotation directe)?
Les bulletins doivent être associés au concept skos http://ontology.irstea.fr/bsv/cropusage/Arboriculture défini dans le thésaurus sur l'usage des cultures
SELECT DISTINCT ?bsv
WHERE {
?bsv a vespa:Bulletin.
?bsv dcterms:subject cropusage:Arboriculture.
?bsv dcterms:date ?dt .
FILTER ( (?dt >= "2015-07-15T00:00:00+02:00"^^xsd:dateTime) && (?dt < "2015-08-15T00:00:00+02:00"^^xsd:dateTime) )
}
Quels sont les bulletins publiés entre le 15 juillet 2013 et 15 août 2015 heure de Paris et qui traitent d'Arboriculture (annotation indirecte)?
Cette fois le bulletin n'est pas forcément associé directement au concept skos Arboriculture, mais par l'un de ces concepts fils. La requête utilise le lien skos:broader défini dans le thésaurus sur l'usage des cultures.
SELECT DISTINCT ?bsv
WHERE {
?bsv a vespa:Bulletin ;
dcterms:subject ?concept ;
dcterms:date ?dt .
?concept skos:broader* cropusage:Arboriculture.
FILTER ( (?dt >= "2015-07-15T00:00:00+02:00"^^xsd:dateTime) && (?dt < "2015-08-15T00:00:00+02:00"^^xsd:dateTime) )
}
100 bulletins publiés de 2009 à 2011 dans la région Alsace en Grande Culture
SELECT DISTINCT ?bsv ?dt ?labconcept ?labregion
WHERE {
?bsv a vespa:Bulletin.
?bsv dcterms:date ?dt .
?bsv dcterms:subject ?concept.
?concept skos:broader* ?parentConcept.
?parentConcept skos:prefLabel ?labconcept.
?bsv dcterms:spatial ?region.
?region rdfs:label ?labregion.
FILTER (
(YEAR(?dt)=2009 || YEAR(?dt)=2010 || YEAR(?dt)=2011) &&
REGEX(?labregion, "alsace", "i") &&
REGEX(?labconcept, "grande culture", "i")
)
}
LIMIT 100
Liste des bulletins publiés entre septembre et novembre en 2011 ou en 2012
SELECT DISTINCT ?mois ?annee ?bsv WHERE {
VALUES ?m { 09 10 11 }.
VALUES ?y { 2011 2012 } .
?bsv a vespa:Bulletin ;
dcterms:date ?dt .
BIND (xsd:integer(SUBSTR(xsd:string(?dt),6,2)) AS ?mois) .
BIND (xsd:integer(SUBSTR(xsd:string(?dt),1,4)) AS ?annee) .
FILTER ( (?mois = ?m) && (?annee = ?y) )
}
Autre solution utilisant les fonctions year et month définies dans la norme sparql 1.1 sur les types de données xsd:DateTime
WHERE {
?document a vespa:Bulletin .
?document dcterms:date ?date.
?document dcterms:date ?dateT.
FILTER ( (YEAR(?date)=2011 || YEAR(?date)=2012) && (MONTH(?date) IN (09, 10, 11)) )
}
Liste des annotations automatiques
Un nouveau graphe indépendant du graphe des annotations de base a été créé pour stocker des annotations suivant le schéma Open Annotation Data Model. Nous avons utilisé l'outil namazu pour construire des annotations automatiques. Le poids des annotations automatiques a été stocké à l'aide de la propriété DUL:hasDataProperty.
PREFIX cnt: <http://www.w3.org/2011/content#>
PREFIX dul:<http://www.loa-cnr.it/ontologies/DUL.owl#>
SELECT ?document ?pdf ?unLabel ?poids ?anno
FROM <http://ontology.irstea.fr:3030/bsv/data/annotation>
WHERE {
?anno oa:hasTarget ?pdf.
?anno oa:hasBody ?unNode.
?anno dul:hasDataValue ?poids.
?unNode cnt:chars ?unLabel.
?anno oa:serializedBy <http://ontology.irstea.fr/bsv/annotation/sofwtare/namazu>.
}
ORDER BY ?pdf
LIMIT 100
les annotations automatiques et manuelles des bulletins de 2011
PREFIX oa: <http://www.w3.org/ns/oa#>
PREFIX cnt: <http://www.w3.org/2011/content#>
PREFIX dul:<http://www.loa-cnr.it/ontologies/DUL.owl#>
SELECT ?pdf ?anno
WHERE {
?bsv vespa:isRealizedBy ?pdf.
?bsv vespa:date_publication ?date. FILTER ( YEAR(?date)=2011)
GRAPH <http://ontology.irstea.fr:3030/bsv/data/annotation>
{
?anno oa:hasTarget ?pdf.
?anno oa:hasBody ?unNode.
}
}
ORDER BY DESC(?pdf)
LIMIT 30